H*****************************************************************
     H*                                                               *
     H*   システム名      :オヤジギャル　　　　　　　　　　　　 *
     H*   サブシステム名  :競馬予想　　　　　　　　　　　　　　 *
     H*   プログラム名    :レース履歴入力　　　　　　　　　　　 *
     H*   プログラムＩＤ  : VAG03                                 *
     H*                                                               *
     H*     作　成　者    :ＨＲＭ　　　　　　　　　　　　　　　 *
     H*     作　成　日    :　　　　　　　　　　　　　　　　　　 *
     H*                                                               *
     H*     変　更　者    :　　　　　　　　　　　　　　　　　　 *
     H*     変　更　日    :　　　　　　　　　　　　　　　　　　 *
     H*                                                               *
     H*  プログラム概要                                             *
     H*C競走馬のレース履歴を登録します。
     H*C
     H*C
     H*C
     H*C
     H*****************************************************************
     H            Y                                     1
     FVAGDB1  IF  E           K        DISK
     FVAGDB2  IF  E           K        DISK
     FVAGDB4L1UF  E           K        DISK                      A
     FGVAG03  CF  E                    WORKSTN
     F                                        RRN1  KSFILE SFLRE1
     F                                              KINFDS CRECNO
     E                    TMSG    1   6 80
     I*----------------------------------------------------*
     I*　　Ｄ　　Ｓ　　　　　　　　　　　　　　　　　　　*
     I*----------------------------------------------------*
     I*
     ICRECNO      DS
     I                                    B 370 3710DSCUR
     I                                    B 378 3790RCDNO
     I*システム日付＆時間
     I            DS
     I                                        1  120D\TIM
     I                                        1   60D\HMS
     I                                        7  120D\YMD
     I                                        7   80D\YY
     I                                        9  100D\MM
     I                                       11  120D\DD
     I*罫線
     I            DS
     I                                        1   2 S#KBFR
     I                                        1   1 GKBFR1
     I                                        2   2 GKBFR2
     I*
     I            DS
     I                                        1  13 GNEN
     I                                        1   10GNEN1
     I                                        2   5 GNEN2
     I                                        6   70GNEN3
     I                                        6   6 GNEN31
     I                                        8  13 GNEN4
     I            DS
     I                                        1   8 GTUK
     I                                        1   20GTUK1
     I                                        1   1 GTUK11
     I                                        3   8 GTUK2
     I            DS
     I                                        1   40GS4MIL
     I                                        1   20KNEN
     I                                        3   40KTUK
     I*
     C*----------------------------------------------------*
     C*    MAIN  CNTROL  PROCESS                           *
     C*----------------------------------------------------*
     C                     EXSR #INIT
     C           \M1       TAG
     C                     EXSR #SCR1
     C   KL
     COR KC                GOTO \END                       ﾌｲｰﾙﾄﾞSET
     C           \M2       TAG
     C                     EXSR #SCR2
     C   KC                GOTO \END
     C   KL                GOTO \M1
     C                     EXSR #UPDT
     C                     GOTO \M1
     C           \END      TAG
     C                     SETON                     LR
     C                     RETRN
     C*----------------------------------------------------*
     C*C初期処理
     C*----------------------------------------------------*
     C           #INIT     BEGSR
     C*
     C*罫線の情報セット
     C                     WRITESCR0
     C                     BITOF'01234567'GKBFR1               ﾋﾞｯﾄ1 ｸﾘｱｰ
     C                     BITOF'01234567'GKBFR2               ﾋﾞｯﾄ2 ｸﾘｱｰ
     C                     BITON'24567'   GKBFR1               ﾋﾞｯﾄ1 ｾｯﾄ
     C                     MOVE 'F'       GKBFR2               ﾋﾞｯﾄ2 ｾｯﾄ
     C                     TIME           D\TIM            *処理日取得
     C                     ENDSR
     C*----------------------------------------------------*
     C*C第一画面処理
     C*----------------------------------------------------*
     C           #SCR1     BEGSR
     C                     SETOF                     30  99
     C                     SETON                     41
     C                     SETOF                     4243
     C                     MOVE *BLANK    G\ERMS
     C                     WRITESCRCLR                     罫線クリア
     C                     WRITESCRK2                      罫線表示
     C                     WRITESFLCT1
     C                     SETOF                     414243
     C                     WRITESCR4
     C           \SCR1     TAG
     C                     WRITESCRE
     C                     EXFMTSCR1
     C                     SETOF                     30  99
     C                     MOVE *BLANK    G\ERMS
     C   KC
     COR KL                GOTO \SCR1E
     C                     EXSR #CHK1
     C   10
     COR 11
     COR 99                GOTO \SCR1
     C           \SCR1E    ENDSR
     C*----------------------------------------------------*
     C*C画面チェック処理
     C*----------------------------------------------------*
     C           #CHK1     BEGSR
     C   KF                DO
     C                     CALL 'VAG08'
     C                     PARM           VA4HCD
     C                     PARM           VA1HNM
     C                     PARM ' '       P\KBN   1
     C                     WRITESCRCLR                     罫線クリア
     C                     WRITESCRK2                      罫線表示
     C*                    WRITESFLCT1
     C*                    SETOF                     414243
     C*                    WRITESCR4
     C                     END
     C   10
     COR 11                DO
     C   10      VA4HCD    SETGTVAGDB1
     C   11      VA4HCD    SETLLVAGDB1
     C   10                DO
     C                     READ VAGDB1                   90
     C   90                DO
     C           *LOVAL    SETLLVAGDB1
     C                     READ VAGDB1                   90
     C                     END
     C                     END
     C   11                DO
     C                     READPVAGDB1                   90
     C   90                DO
     C           *HIVAL    SETLLVAGDB1
     C                     READPVAGDB1                   90
     C                     END
     C                     END
     C  N90                MOVELVA1COD    VA4HCD
     C                     END
     C           VA4HCD    IFEQ *ZERO
     C                     MOVELTMSG,1    G\ERMS
     C                     SETON                     3099
     C                     ELSE
     C           VA4HCD    CHAINVAGDB1               90
     C   90                MOVE *BLANK    VA1HNM
     C   90N99             MOVELTMSG,3    G\ERMS
     C   90                SETON                     3099
     C                     END
     C                     ENDSR
     C*----------------------------------------------------*
     C*C第二画面処理
     C*----------------------------------------------------*
     C           #SCR2     BEGSR
     C                     SETOF                     202122
     C                     SETOF                     232425
     C                     SETOF                     262728
     C                     SETOF                     99
     C                     Z-ADD6         PHLIN
     C                     Z-ADD2         PHPOS
     C                     MOVELTMSG,4    G\ERMS
     C                     EXSR #SEDT
     C                     WRITESCR5
     C                     WRITESCR1
     C           \SCR2     TAG
     C                     WRITESCRE
     C                     EXFMTSFLCT1
     C           DSCUR     DIV  256       PHLIN
     C                     MVR            PHPOS
     C                     Z-ADDRCDNO     G\RNO
     C                     SETOF                     202122
     C                     SETOF                     232425
     C                     SETOF                     262728
     C                     SETOF                     99
     C                     MOVELTMSG,4    G\ERMS
     C   KC
     COR KL                GOTO \SCR2E
     C   77                EXSR #HELP
     C                     EXSR #CHK2
     C  N99 KI             GOTO \SCR2E
     C                     GOTO \SCR2
     C           \SCR2E    ENDSR
     C*----------------------------------------------------*
     C*Cサブファイル編集処理
     C*----------------------------------------------------*
     C           #SEDT     BEGSR
     C*
     C                     Z-ADD0         RRN1    40
     C                     SETOF                     202122
     C                     SETOF                     232425
     C                     SETOF                     262728
     C*
     C                     SETON                         43* SFL ｸﾘｱ
     C                     SETOF                     4142
     C                     WRITESFLCT1
     C                     SETOF                         43
     C*
     C           VA4HCD    SETLLVAGDB4L1
     C           VA4HCD    READEVAGDB4L1                 90
     C                     Z-ADD1         G\RNO
     C           *IN90     DOWEQ'0'
     C                     ADD  1         RRN1
     C           RRN1      DIV  2         W\CMP1 100
     C                     MVR            W\CMP2 100
     C                     SETOF                     32
     C           W\CMP2    IFEQ 0
     C                     SETON                     32
     C                     END
     C                     Z-ADDVA4YMD    GS4YMD
     C                     Z-ADDVA4YMD    GS4HMD
     C                     Z-ADDVA4KKA    GS4KKA
     C                     MOVE VA4KYU    GS4KYU
     C                     Z-ADDVA4MIL    GS4MIL
     C                     Z-ADDVA4KCD    GS4KCD
     C                     Z-ADDVA4GTO    GS4GTO
     C                     Z-ADDVA4HND    GS4HND
     C                     Z-ADDVA4AGR    GS4AGR
     C                     Z-ADDVA4TNK    GS4TNK
     C                     MOVEL*BLANK    GSKYUN
     C           GS4KYU    IFEQ '1'
     C                     MOVEL'未勝利'GSKYUN
     C                     END
     C           GS4KYU    IFEQ '2'
     C                     MOVEL'500万' GSKYUN
     C                     END
     C           GS4KYU    IFEQ '3'
     C                     MOVEL'900万' GSKYUN
     C                     END
     C           VA4KYU    IFEQ '4'
     C                     MOVEL'1500万'GSKYUN
     C                     END
     C           VA4KYU    IFEQ '5'
     C                     MOVEL'ｵｰﾌﾟﾝ'   GSKYUN
     C                     END
     C           VA4KYU    IFEQ '6'
     C                     MOVEL'Ｇ�L'  GSKYUN
     C                     END
     C           VA4KYU    IFEQ '7'
     C                     MOVEL'Ｇ�K'  GSKYUN
     C                     END
     C           VA4KYU    IFEQ '8'
     C                     MOVEL'Ｇ�J'  GSKYUN
     C                     END
     C           VA4KYU    IFEQ '9'
     C                     MOVEL'休養'  GSKYUN
     C                     END
     C           VA4KYU    IFEQ 'A'
     C                     MOVEL'障害'  GSKYUN
     C                     END
     C           VA4KYU    IFNE '9'
     C           VA4KCD    CHAINVAGDB2               91
     C  N91                MOVE VA2NMJ    GSKSNM
     C   91                MOVE *BLANK    GSKSNM
     C                     ELSE
     C           GS4MIL    IFNE *ZERO
     C           KNEN      IFNE *ZERO
     C                     MOVE *BLANK    GSKSNM
     C                     MOVE *BLANK    GNEN
     C                     Z-ADDKNEN      GNEN1
     C                     MOVEL'年'    GNEN2
     C           KTUK      IFNE *ZERO
     C                     Z-ADDKTUK      GNEN3
     C           GNEN31    IFEQ '0'
     C                     MOVEL*BLANK    GNEN31
     C                     END
     C                     MOVEL'ヵ月'  GNEN4
     C                     END
     C                     MOVE GNEN      GSKSNM
     C                     ELSE
     C                     MOVE *BLANK    GSKSNM
     C                     MOVE *BLANK    GTUK
     C                     Z-ADDKTUK      GTUK1
     C           GTUK11    IFEQ '0'
     C                     MOVEL*BLANK    GTUK11
     C                     END
     C                     MOVEL'ヵ月'  GTUK2
     C                     MOVE GTUK      GSKSNM
     C                     END
     C                     END
     C                     END
     C                     WRITESFLRE1
     C           VA4HCD    READEVAGDB4L1                 90
     C                     END
     C*
     C           RRN1      ADD  1         I       20
     C           I         DO   51        RRN1
     C           RRN1      DIV  2         W\CMP1 100
     C                     MVR            W\CMP2 100
     C                     SETOF                     32
     C           W\CMP2    IFEQ 0
     C                     SETON                     32
     C                     END
     C                     Z-ADD*ZERO     GS4YMD
     C                     Z-ADD*ZERO     GS4HMD
     C                     Z-ADD*ZERO     GS4KKA
     C                     MOVE *BLANK    GS4KYU
     C                     Z-ADD*ZERO     GS4MIL
     C                     Z-ADD*ZERO     GS4KCD
     C                     Z-ADD*ZERO     GS4GTO
     C                     Z-ADD*ZERO     GS4HND
     C                     Z-ADD*ZERO     GS4AGR
     C                     Z-ADD*ZERO     GS4TNK
     C                     MOVE *BLANK    GSKYUN
     C                     MOVE *BLANK    GSKSNM
     C                     WRITESFLRE1
     C                     END
     C           RRN1      IFEQ 0                          * ｻﾌﾞﾌｧｲﾙ無
     C                     MOVEA'10'      *IN,41
     C                     SETON                     80
     C                     ELSE                            * ｻﾌﾞﾌｧｲﾙ有
     C                     MOVEA'11'      *IN,41
     C                     END
     C           *LOVAL    SETLLVAGDB4L1
     C*
     C           #SEDTE    ENDSR
     C*----------------------------------------------------*
     C*CＨＥＬＰ画面処理
     C*----------------------------------------------------*
     C           #HELP     BEGSR
     C           DSCUR     DIV  256       LINE    20
     C                     MVR            COL     20
     C           LINE      IFGE 6
     C           LINE      ANDLE22
     C           COL       ANDGE2
     C           COL       ANDLE80
     C           LINE      SUB  6         RRN1
     C                     ADD  RCDNO     RRN1
     C                     SETOF                     88
     C           COL       IFEQ 19
     C                     MOVEL'1'       P\KBN
     C                     SETON                     88
     C                     END
     C  N88      COL       IFGE 33
     C           COL       ANDLE36
     C                     MOVEL'2'       P\KBN
     C                     SETON                     88
     C                     END
     C  N88      COL       IFGE 40
     C           COL       ANDLE43
     C                     MOVEL'3'       P\KBN
     C                     SETON                     88
     C                     END
     C  N88      COL       IFGE 61
     C           COL       ANDLE70
     C                     MOVEL'4'       P\KBN
     C                     SETON                     88
     C                     END
     C  N88      COL       IFGE 77
     C           COL       ANDLE78
     C                     MOVEL'6'       P\KBN
     C                     SETON                     88
     C                     END
     C  N88                MOVEL'5'       P\KBN
     C                     CALL 'VAG031'
     C                     PARM           P\KBN   1
     C                     PARM           P\KYU   1
     C           P\KBN     IFEQ '1'
     C           P\KBN     OREQ '4'
     C           P\KBN     OREQ '6'
     C           RRN1      CHAINSFLRE1               90
     C           *IN90     IFEQ '0'
     C           P\KBN     IFEQ '1'
     C                     MOVELP\KYU     GS4KYU
     C                     END
     C           P\KBN     IFEQ '4'
     C                     MOVEL*BLANK    GS4GTO
     C                     MOVE P\KYU     GS4GTO
     C                     END
     C           P\KBN     IFEQ '6'
     C                     MOVELP\KYU     GS4TNK
     C                     END
     C                     UPDATSFLRE1
     C                     END
     C                     END
     C                     END
     C           \HELPE    ENDSR
     C*----------------------------------------------------*
     C*C第二画面チェック処理
     C*----------------------------------------------------*
     C           #CHK2     BEGSR
     C                     Z-ADD1         RRN1
     C                     SETOF                     99
     C                     MOVELTMSG,4    G\ERMS
     C           RRN1      CHAINSFLRE1               90
     C           *IN90     DOWEQ'0'
     C                     SETOF                     202122
     C                     SETOF                     232425
     C                     SETOF                     262728
     C                     EXSR #CHK21
     C           RRN1      DIV  2         W\CMP1 100
     C                     MVR            W\CMP2 100
     C                     SETOF                     32
     C           W\CMP2    IFEQ 0
     C                     SETON                     32
     C                     END
     C   99      RRN1      IFLE G\RNO
     C                     Z-ADDRRN1      G\RNO
     C                     END
     C                     UPDATSFLRE1
     C                     ADD  1         RRN1
     C           RRN1      CHAINSFLRE1               90
     C                     END
     C           \CHK2E    ENDSR
     C*----------------------------------------------------*
     C*C第二画面チェック処理２ 　
     C*----------------------------------------------------*
     C           #CHK21    BEGSR
     C           GS4YMD    IFEQ *ZERO
     C           GS4HMD    ANDEQ*ZERO
     C           GS4KKA    ANDEQ*ZERO
     C           GS4KYU    ANDEQ*BLANK
     C           GS4MIL    ANDEQ*ZERO
     C           GS4KCD    ANDEQ*ZERO
     C           GS4GTO    ANDEQ*ZERO
     C           GS4HND    ANDEQ*ZERO
     C                     GOTO \CK21E
     C                     END
     C*          GS4YMD    IFEQ *ZERO
     C*                    MOVELTMSG,1    G\ERMS
     C*                    SETON                     2099
     C*                    END
     C           GS4KYU    IFNE '9'
     C           GS4KKA    ANDEQ*ZERO
     C  N99                MOVELTMSG,1    G\ERMS
     C                     SETON                     2199
     C                     ELSE
     C           GS4KYU    IFEQ '9'
     C           GS4KKA    ANDNE*ZERO
     C  N99                MOVELTMSG,5    G\ERMS
     C                     SETON                     2199
     C                     END
     C                     END
     C           GS4KYU    IFEQ *BLANK
     C  N99                MOVELTMSG,1    G\ERMS
     C                     SETON                     2299
     C                     ELSE
     C           GS4KYU    IFEQ '0'
     C           GS4KYU    OREQ '1'
     C           GS4KYU    OREQ '2'
     C           GS4KYU    OREQ '3'
     C           GS4KYU    OREQ '4'
     C           GS4KYU    OREQ '5'
     C           GS4KYU    OREQ '6'
     C           GS4KYU    OREQ '7'
     C           GS4KYU    OREQ '8'
     C           GS4KYU    OREQ '9'
     C           GS4KYU    OREQ 'A'
     C                     MOVEL*BLANK    GSKYUN
     C           GS4KYU    IFEQ '1'
     C                     MOVEL'未勝利'GSKYUN
     C                     END
     C           GS4KYU    IFEQ '2'
     C                     MOVEL'500万' GSKYUN
     C                     END
     C           GS4KYU    IFEQ '3'
     C                     MOVEL'900万' GSKYUN
     C                     END
     C           GS4KYU    IFEQ '4'
     C                     MOVEL'1500万'GSKYUN
     C                     END
     C           GS4KYU    IFEQ '5'
     C                     MOVEL'ｵｰﾌﾟﾝ'   GSKYUN
     C                     END
     C           GS4KYU    IFEQ '6'
     C                     MOVEL'Ｇ�L'  GSKYUN
     C                     END
     C           GS4KYU    IFEQ '7'
     C                     MOVEL'Ｇ�K'  GSKYUN
     C                     END
     C           GS4KYU    IFEQ '8'
     C                     MOVEL'Ｇ�J'  GSKYUN
     C                     END
     C           GS4KYU    IFEQ '9'
     C                     MOVEL'休養'  GSKYUN
     C                     END
     C           GS4KYU    IFEQ 'A'
     C                     MOVEL'障害'  GSKYUN
     C                     END
     C                     ELSE
     C  N99                MOVELTMSG,2    G\ERMS
     C                     MOVEL*BLANK    GSKYUN
     C                     SETON                     2299
     C                     END
     C                     END
     C           GS4MIL    IFEQ *ZERO
     C  N99                MOVELTMSG,1    G\ERMS
     C                     SETON                     2399
     C                     END
     C           GS4KCD    IFEQ *ZERO
     C           GS4KYU    IFNE '9'
     C  N99                MOVELTMSG,1    G\ERMS
     C                     SETON                     232499
     C                     MOVE *BLANK    GSKSNM
     C                     END
     C                     ELSE
     C           GS4KCD    IFEQ 9999
     C                     CALL 'VAG09'
     C                     PARM           GS4KCD
     C                     PARM           GSKSNM
     C                     PARM ' '       P\KBN   1
     C                     WRITESCRCLR                     罫線クリア
     C                     WRITESCRK2                      罫線表示
     C                     WRITESCR1
     C                     WRITESCR4
     C                     END
     C                     END
     C           GS4KYU    IFNE '9'
     C           GS4KCD    IFNE *ZERO
     C           GS4KCD    CHAINVAGDB2               91
     C  N91                MOVE VA2NMJ    GSKSNM
     C   91                MOVE *BLANK    GSKSNM
     C  N99 91             MOVELTMSG,3    G\ERMS
     C      91             SETON                     2499
     C                     END
     C                     ELSE
     C           GS4MIL    IFNE *ZERO
     C           KNEN      IFNE *ZERO
     C                     MOVE *BLANK    GSKSNM
     C                     MOVE *BLANK    GNEN
     C                     Z-ADDKNEN      GNEN1
     C                     MOVEL'年'    GNEN2
     C           KTUK      IFNE *ZERO
     C                     Z-ADDKTUK      GNEN3
     C           GNEN31    IFEQ '0'
     C                     MOVEL*BLANK    GNEN31
     C                     END
     C                     MOVEL'ヵ月'  GNEN4
     C                     END
     C                     MOVE GNEN      GSKSNM
     C                     ELSE
     C                     MOVE *BLANK    GSKSNM
     C                     MOVE *BLANK    GTUK
     C           KTUK      IFNE *ZERO
     C                     Z-ADDKTUK      GTUK1
     C           GTUK11    IFEQ '0'
     C                     MOVEL*BLANK    GTUK11
     C                     END
     C                     MOVEL'ヵ月'  GTUK2
     C                     MOVE GTUK      GSKSNM
     C                     END
     C                     END
     C                     END
     C                     END
     C           GS4GTO    IFEQ *ZERO
     C  N99                MOVELTMSG,1    G\ERMS
     C                     SETON                     2599
     C                     END
     C           GS4KYU    IFNE '9'
     C           GS4HND    ANDEQ*ZERO
     C  N99                MOVELTMSG,1    G\ERMS
     C                     SETON                     2699
     C                     ELSE
     C           GS4KYU    IFEQ '9'
     C           GS4HND    ANDNE*ZERO
     C  N99                MOVELTMSG,5    G\ERMS
     C                     SETON                     2699
     C                     END
     C                     END
     C           GS4KYU    IFEQ '9'
     C           GS4AGR    ANDNE*ZERO
     C  N99                MOVELTMSG,5    G\ERMS
     C                     SETON                     2799
     C                     END
     C           GS4KYU    IFEQ '9'
     C           GS4TNK    ANDNE*ZERO
     C  N99                MOVELTMSG,5    G\ERMS
     C                     SETON                     2899
     C                     END
     C           GS4KYU    IFNE '9'
     C           GS4TNK    ANDGE4
     C  N99                MOVELTMSG,6    G\ERMS
     C                     SETON                     2899
     C                     END
     C           \CK21E    ENDSR
     C*----------------------------------------------------*
     C*C更新処理
     C*----------------------------------------------------*
     C           #UPDT     BEGSR
     C                     Z-ADD1         RRN1
     C           RRN1      CHAINSFLRE1               90
     C           *IN90     DOWEQ'0'
     C           RRN1      DIV  2         W\CMP1 100
     C                     MVR            W\CMP2 100
     C                     SETOF                     32
     C           W\CMP2    IFEQ 0
     C                     SETON                     32
     C                     END
     C                     UPDATSFLRE1
     C                     EXSR #UP
     C                     ADD  1         RRN1
     C           RRN1      CHAINSFLRE1               90
     C                     END
     C                     ENDSR
     C*----------------------------------------------------*
     C*C更新処理２
     C*----------------------------------------------------*
     C           #UP       BEGSR
     C           GS4HMD    IFEQ *ZERO
     C           GS4YMD    ANDEQ*ZERO
     C           GS4KKA    ANDEQ*ZERO
     C           GS4KYU    ANDEQ*BLANK
     C           GS4MIL    ANDEQ*ZERO
     C           GS4KCD    ANDEQ*ZERO
     C           GS4GTO    ANDEQ*ZERO
     C           GS4HND    ANDEQ*ZERO
     C                     GOTO \UPE
     C                     END
     C           KVAG4     KLIST
     C                     KFLD           VA4HCD
     C                     KFLD           VA4YMD
     C           GS4HMD    IFLE 500000
     C                     Z-ADD20000000  VA4YMD
     C                     ELSE
     C                     Z-ADD19000000  VA4YMD
     C                     END
     C                     ADD  GS4HMD    VA4YMD
     C           KVAG4     CHAINVAGDB4L1             91
     C                     Z-ADDGS4YMD    VA4YMD
     C           GS4YMD    IFLE 500000
     C                     ADD  20000000  VA4YMD
     C                     ELSE
     C                     ADD  19000000  VA4YMD
     C                     END
     C                     Z-ADDGS4KKA    VA4KKA
     C                     MOVE GS4KYU    VA4KYU
     C                     Z-ADDGS4MIL    VA4MIL
     C                     Z-ADDGS4KCD    VA4KCD
     C                     Z-ADDGS4GTO    VA4GTO
     C                     Z-ADDGS4HND    VA4HND
     C                     Z-ADDGS4AGR    VA4AGR
     C                     Z-ADDGS4TNK    VA4TNK
     C           *IN91     IFEQ '0'
     C           GS4YMD    IFEQ *ZERO
     C                     DELETVAG4R
     C                     ELSE
     C           GS4HMD    IFEQ GS4YMD
     C                     UPDATVAG4R
     C                     ELSE
     C                     DELETVAG4R
     C                     WRITEVAG4R
     C                     END
     C                     END
     C                     ELSE
     C           GS4YMD    IFNE *ZERO
     C                     WRITEVAG4R
     C                     END
     C                     END
     C           \UPE      ENDSR
**
必須入力です。
区分エラー（０〜Ａ）
マスター未登録
 コード未定時　�V９９９９�Vを入力して下さい。
休養の時は、距離と騎手コードのみ入力可能です。
区分エラー（0:良1:やや重2:重3:不良)